Meson WrapDB for Google's cityhash.
Nelze vybrat více než 25 témat Téma musí začínat písmenem nebo číslem, může obsahovat pomlčky („-“) a může být dlouhé až 35 znaků.

configure.ac 2.1KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677
  1. m4_define([cityhash_major], [1])
  2. m4_define([cityhash_minor], [1])
  3. m4_define([cityhash_patchlevel], [1])
  4. # Libtool shared library interface versions (current:revision:age)
  5. # Update this value for every release! (A:B:C will map to foo.so.(A-C).C.B)
  6. # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  7. m4_define([cityhash_ltversion], [4:0:0])
  8. AC_PREREQ([2.65])
  9. AC_INIT([CityHash], [cityhash_major.cityhash_minor.cityhash_patchlevel], [cityhash-discuss@googlegroups.com])
  10. AC_CONFIG_HEADERS([config.h])
  11. AM_INIT_AUTOMAKE([1.10 no-define foreign])
  12. LT_PREREQ([2.2])
  13. LT_INIT
  14. AC_CONFIG_FILES([Makefile
  15. src/Makefile])
  16. AC_CONFIG_SRCDIR([src/city.h])
  17. AC_CONFIG_MACRO_DIR([m4])
  18. AC_ARG_ENABLE([sse4.2],
  19. AS_HELP_STRING("Build CityHash variants that depend on the _mm_crc32_u64 intrinsic."),
  20. [ cityhash_sse42=true ],
  21. [])
  22. AM_CONDITIONAL([SSE42], [test x$cityhash_sse42 = xtrue ])
  23. # Checks for programs.
  24. AC_PROG_CXX
  25. AC_LANG([C++])
  26. AC_C_BIGENDIAN
  27. # Checks for libraries.
  28. # Checks for header files.
  29. AC_CHECK_HEADERS([stdint.h stdlib.h])
  30. # Checks for typedefs, structures, and compiler characteristics.
  31. AC_C_INLINE
  32. AC_TYPE_SIZE_T
  33. AC_TYPE_SSIZE_T
  34. AC_TYPE_UINT32_T
  35. AC_TYPE_UINT64_T
  36. AC_TYPE_UINT8_T
  37. # Check for __builtin_expect
  38. AC_MSG_CHECKING([if the compiler supports __builtin_expect])
  39. AC_COMPILE_IFELSE(
  40. [AC_LANG_PROGRAM(, [[return __builtin_expect(1, 1) ? 1 : 0;]])],
  41. [
  42. cityhash_have_builtin_expect=yes
  43. AC_MSG_RESULT([yes])
  44. ], [
  45. cityhash_have_builtin_expect=no
  46. AC_MSG_RESULT([no])
  47. ])
  48. if test x$cityhash_have_builtin_expect = xyes ; then
  49. AC_DEFINE([HAVE_BUILTIN_EXPECT], [1], [Define to 1 if the compiler supports __builtin_expect.])
  50. fi
  51. AC_OUTPUT
  52. echo \
  53. "-------------------------------------------------
  54. ${PACKAGE_NAME} Version ${PACKAGE_VERSION}
  55. Prefix: '${prefix}'.
  56. Compiler: '${CXX} ${CXXFLAGS}'
  57. Now type 'make @<:@<target>@:>@'
  58. where the optional <target> is:
  59. all - build everything
  60. check - build and run tests
  61. install - install everything
  62. --------------------------------------------------"